Find all subgroups of GL(3,7) with a Sylow 3-subgroup of order 27

Question

I want to use GAP to study all subgroups of GL(3,7) with a Sylow 3-subgroup of order 27. How can I do it? Thanks.

Just list the subgroups (FAQ 7.7) and pass it through a filter, no? — user10354138, Feb 23 '21 at 05:19
Also, you can find this useful for learning GAP: https://carpentries-incubator.github.io/gap-lesson/ is a Software Carpentry style lesson using some group-theoretic question as an example. — Olexandr Konovalov, Feb 23 '21 at 22:58

score 2 · Answer 1 · answered Feb 24 '21 at 20:57

Just so that the question is answered, this group is small enough that one can easily compute all subgroups of the group $G$, and select those of a suitable order. This is easiest done in an isomorphic permutation group.

gap> G:=GL(3,7);;
gap> iso:=IsomorphismPermGroup(G);;p:=Image(iso);
<permutation group of size 33784128 with 2 generators>
gap> u:=List(ConjugacyClassesSubgroups(p),Representative);;
gap> u:=Filtered(u,x->Size(x) mod 27=0 and Size(x) mod 81<>0);;
gap> Length(u);
163
gap> u:=List(u,x->PreImage(iso,x));;

finds 163 classes of subgroups. If the group gets bigger and calculating all subgroups becomes infeasible, one could try to compute the potential Sylow subgroups first (from the subgroups of a Sylow subgroup of $G$), and use IntermediateSubgroups to find all subgroups above, and finally fuse under the conjugaction action:

gap> s:=SylowSubgroup(p,3);
<permutation group of size 81 with 4 generators>
gap> m:=MaximalSubgroupClassReps(s);
[ <permutation group with 3 generators>, <permutation group with 3 generators>
    , <permutation group with 3 generators>,
  <permutation group with 3 generators> ]

Fuse under full group:

gap> m:=List(SubgroupsOrbitsAndNormalizers(p,m,false),x->x.representative);
[ <permutation group of size 27 with 3 generators>,
  <permutation group of size 27 with 3 generators>,
  <permutation group of size 27 with 3 generators> ]
gap> int:=List(m,x->IntermediateSubgroups(p,x).subgroups);;
gap> int:=Unique(Concatenation(int));;
gap> int:=Filtered(int,x->Size(x) mod 81<>0);;

Again eliminate conjugates.

gap> int:=List(SubgroupsOrbitsAndNormalizers(p,int,false),x->x.representative);;
gap> Length(int)+Length(m);
163

Find all subgroups of GL(3,7) with a Sylow 3-subgroup of order 27

1 Answers1