2

Let $V(FA_4)$ be normalized unit group of group algebra $FA_4$, where $F$ is a field containing 4 elements and $A_4$ is alternating group on $4$ symbols. How can I find conjugacy classes of elements of $V$ using GAP commands? ( Since GAP has most commands for $p$-groups over finite field $F_p$ )

HIMANSHU
  • 196

1 Answers1

2

There probably is a better way of finding units -- what I will use is to work in the regular matrix representation, since it will give the units as a group of matrices.

Start with the regular matrix representation:

gap> g:=AlternatingGroup(4);;
gap> g:=Image(RegularActionHomomorphism(g));
Group([ (1,5,7)(2,4,8)(3,6,9)(10,11,12), (1,2,3)(4,7,10)(5,9,11)(6,8,12) ])
gap> mats:=List(GeneratorsOfGroup(g),x->PermutationMat(x,Size(g),GF(4)));

For performance reasons it turns out to be useful to change the basis so that the algebra is a direct sum of smaller dimensional algebras:

gap> bas:=List(MTX.Indecomposition(GModuleByMats(mats,GF(4))),x->x[1]);;
gap> bas:=Concatenation(bas)^-1;
< mutable compressed matrix 12x12 over GF(4) >
gap> mats:=List(mats,x->x^bas);;

(Verify block form with Display(mats[1]);). Now we form the algebra:

gap> r:=Algebra(GF(4),mats);
<algebra over GF(2^2), with 2 generators>
gap> Size(r);
16777216

Now we start searching for units:

u:=Group(mats);
for e in Enumerator(r) do
  if not IsZero(DeterminantMat(e)) and not e in u then
    Print("Found extra generator\n");
    u:=ClosureGroup(u,e:cheap);
    Print("Units now size ",Size(u),"\n");
  fi;
od;

This runs a bit and gives us a group of matrices:

gap> u;
<matrix group of size 7077888 with 11 generators>

For efficiency we cnonvert the unit group (which happens to be solvable) to a PcGroup:

gap> iso:=IsomorphismPcGroup(u);;
gap> v:=Image(iso,u);;

and compute its conjugacy classes:

gap> cl:=ConjugacyClasses(v);;
gap> Collected(List(cl,Size));
#G  FULL 1226870/ 109503kb live   906133/  99953kb dead    19000/ 371712kb free
[ [ 1, 192 ], [ 12, 720 ], [ 144, 5400 ], [ 256, 1152 ], [ 3072, 1440 ],
  [ 4096, 384 ] ]
ahulpke
  • 18,416
  • 1
  • 21
  • 38
  • Thanks for such an amazing description. By your approach, I can classify the possible lengths for conjugacy classes. Actually I started with the group presentation of $A_4$ in terms of $2$ generators $a$ and $b$ and taken the non-zero field elements as cube roots of unity $\omega$. Next, I tried to find the class length of some specific element of $V(FA_4)$ (Normalized Unit Group of $FA_4$). It is taking too long as the group size is $(9).(4^9)$. Can you give a direction ? – HIMANSHU Dec 03 '21 at 06:42
  • Are you asking a separate question? I don't understand this remark. – ahulpke Dec 03 '21 at 14:00
  • Yes. I want class length of a particular element inside V. Am I making sense now or should I elaborate a bit? – HIMANSHU Dec 03 '21 at 16:51
  • The class length of a particular element is simply the index of its Centralizer. – ahulpke Dec 03 '21 at 17:14
  • Exactly. How can I calculate centralizer of a particular element in this large group using GAP ? It will take too long to check. – HIMANSHU Dec 03 '21 at 17:17
  • In the example I gave you, thecentralizer calculation will take seconds at best. – ahulpke Dec 03 '21 at 17:19
  • Let me elaborate. I have taken $A_4=\left<a,b : a^2 =b^3 =1, (ab)^3=1\right>$ and $F= GF(4)={0,1,\omega,{\omega}^2 }$, where $\omega$ is the cube root of unity. Next, I took $v_1=1+\omega(b+b^2) \in V(FA_4)$. Furthermore, I am picking element $w_1$ from the centralizer $C_V(v_1)$ and trying to find its conjugacy class. It is taking too long to compute in GAP. Please guide. – HIMANSHU Dec 03 '21 at 17:35
  • You are basically asking a different question. Post it as a new question and include the commands you are using. – ahulpke Dec 04 '21 at 02:10
  • Let us continue this discussion in chat. – HIMANSHU Dec 04 '21 at 04:21