2

I have a function that I want to study it's asymptotic behavior.

The function is

$$ f(k) = - \frac{k^2}{4} - \frac{\log\pi}{2} + \log\left( \frac12 \left| \mathrm{Erfi}(\frac{k}{2} - \pi i) - \mathrm{Erfi}(\frac{k}{2} + \pi i)\right|\right) $$

and k takes only positive integer.

The plot of this function looks like:

ListPlot[Table[f[k], {k, 0, 100}], PlotRange -> All]

enter image description here

It looks like that the function has a asymptotic behavior (looks like ~ Log[k]), could we find a way to extract the main term (the coefficient of the Log[k] if behave like log)?

From here and here, I find the mainTerm function, but it seems to have ignored the big Log term and not work in this case:

mainTerm[f[k], k]
(* -(k^2/4) *)
Community
  • 1
xslittlegrass
  • 471
  • 1
    Normal@Series[f[k], {k, \[Infinity], 3}] – Sektor May 07 '14 at 05:27
  • possible duplicate of Growth of functions – Sektor May 07 '14 at 05:28
  • @Sektor I guess I don't understand what's the point to expand it to the third order, are you saying that it's divergent? Also after reading the post you linked, I still can't figure out the answer to my question. I'm looking for an expression that can match the function f at large k. – xslittlegrass May 07 '14 at 06:40
  • While not a complete Mathematica answer, it looks like -2 Log[k]. Sektor has given you the right start, but you will also need to help Mathematica a bit as well. – chuy May 07 '14 at 14:44
  • @chuy I still don't quiet understand. Could you say more of what I need to help Mathematica to do? – xslittlegrass May 07 '14 at 15:07
  • For those who haven't actually looked at this the function is highly oscillatory, and only looks as nice as it does because he's list plotting over integers. Is that what you want to study (the integer values? ) – george May 07 '14 at 20:48
  • @george2079 Yes, exactly. The function is defined at only the integer values. – xslittlegrass May 07 '14 at 20:50
  • you are evaluating it for integers, but it is defined for all k. That makes a mess of any sort of direct limit analysis. See my first comment.. – george May 07 '14 at 21:13
  • @george2079 OK, I see you points. I have flagged a request to move it. Thanks! – xslittlegrass May 07 '14 at 22:08

2 Answers2

2

If it helps your expression simplifies to this:

 f[k_] = Log[Exp[-k^2]/(2 Pi)^2 (Erf[I k/2 - Pi] - Erf[I k/2 + Pi])^4]/4

or 

 f[k_] = Log[Exp[-k^2]/(2 Pi)^2 (Re[Erf[I k/2 - Pi]])^4]/4

(making the assumption k is real )

george
  • 131
  • 5
2

This is more of a Mathematica answer than a Mathematics answer. As george indicated we can write

$$ f(k) = \frac{1}{4}\log\left\{ \frac{\exp(-k^2)}{(2\pi)^2} \operatorname{Re}\left[\operatorname{erf}\left(\frac{ik}{2}-\pi\right)\right]^4\right\} + \frac{\log 2}{2}. $$

(Note the constant term $\log 2/2$ which was missing from george's answer.) The question really comes down to estimating $\operatorname{Re}\left[\operatorname{erf}\left(\frac{ik}{2}-\pi\right)\right]$ as $k \to \infty$.

In Mathematica we enter

Series[Erf[I k/2 - Pi], {k, \[Infinity], 2}]

which yields

$$ i^{2 \text{Floor}\left[\frac{\text{Arg}\left[-i k \pi +\pi ^2\right]}{2 \pi }\right]}+e^{\frac{k^2}{4}+i k \pi } \left(\frac{2 i e^{-\pi ^2}}{\sqrt{\pi } k}+\frac{4 e^{-\pi ^2} \sqrt{\pi }}{k^2}+O\left[\frac{1}{k}\right]^3\right). $$

The reason we expand to second order is that we know $k$ will be an integer and hence $e^{ik\pi} = \pm 1$. So, when we take the real part, the first term in the parentheses, being purely imaginary, will disappear.

We continue with

Re[% // Normal] // ComplexExpand

which yields

$$ \frac{4 e^{\frac{k^2}{4}-\pi ^2} \sqrt{\pi } \text{Cos}[k \pi ]}{k^2}+\text{Cos}\left[\pi \text{Floor}\left[\frac{\text{Arg}\left[-i k \pi +\pi ^2\right]}{2 \pi }\right]\right]-\frac{2 e^{\frac{k^2}{4}-\pi ^2} \text{Sin}[k \pi ]}{k \sqrt{\pi }}. $$

Now the second term is $O(1)$ which is much smaller than the first term and the third term is zero since $\sin(k\pi) = 0$, so to find the leading order we'll just take the first term.

The argument in the $\log$ term in $f$ is then, to first order,

E^(-k^2)/(2 Pi)^2 ((4 E^(k^2/4 - \[Pi]^2) Sqrt[\[Pi]] Cos[k \[Pi]])/k^2)^4

$$ \frac{64 e^{-4 \pi ^2} \text{Cos}[k \pi ]^4}{k^8}. $$

Of course $\cos(k\pi)^4 = 1$ so we conclude that

$$ f(k) \approx \frac{1}{4} \log\left(\frac{64 e^{-4 \pi ^2}}{k^8}\right) + \frac{\log 2}{2}. $$

To simplify this a little we could use

Simplify[Log[(64 E^(-4 \[Pi]^2))/k^8]/4 + Log[2]/2, Assumptions -> k > 0]

to get

$$ f(k) \approx -2\log k - \pi^2 + \log 4. $$

Here's a plot of this approximation in red versus the numerical points in blue.

enter image description here

Antonio Vargas
  • 24,993